Exécuter une requête dans un thread

Date de publication : 17/11/2004

Par Bloon (Retour Index)
 

Cet article présente l'exécution d'une requête dans un Thread avec Delphi

Introduction

1. Définition

2. Quand exécuter une requête dans un thread ?

• ne nécessitant pas l'intervention de l'utilisateur : il pourrait être surpris de voir surgir tout à coup une boîte de dialogue alors qu'il n'a rien demandé et qu'il est en train de faire autre chose.
• non critiques pour l'utilisation de l'application : il est inutile de rendre la main à l'utilisateur si l'exécution de la requête conditionne l'utilisation de l'application.

3. Principes généraux

• L'action à threader (Open) doit se trouver dans la méthode Execute. Il ne faut pas que le Open engendre des appels à la VCL, il faut donc :
• Détacher le TDataSet du TDataSource (sinon les contrôles attachés seront mis à jour)
• Renseigner les paramètres de connexion (login/mot de passe) avant l'exécution de la requête et empêcher l'affichage de la boite de dialogue qui les demande (LoginPrompt à false)
• Les éventuels appels à la VCL (écriture dans un contrôle par exemple) doivent être faits dans des méthodes appelées par Synchronize

4. Mise en oeuvre

4.1. Déclaration de la classe

Déclaration de la classe TDataSetThread
Uses Classes, DB;

TDataSetThread = class(TThread)
protected
  FDataSet : TDataSet;
  FDataSource : TDataSource;
  FMessages : TStrings;
  FMessage : string;
  procedure initialisation(pDataSet : TDataSet; pDataSource : TDataSource; pMessages : TStrings);
  procedure EcrireMessage;
  procedure FinTraitement;
  procedure Execute; override;
public
  constructor Create(pDataSet : TDataSet; pMessages : TStrings = nil); overload;
  constructor Create(pDataSource : TDataSource; pMessages : TStrings = nil); overload;
end;

4.2. Les constructeurs

Constructeurs et initialisation
Uses SysUtils;

procedure TDataSetThread.initialisation(pDataSet: TDataSet; pDataSource: TDataSource; pMessages: TStrings);
begin
  FDataSource := pDataSource;
  FDataSet := pDataSet;
  if assigned(FDataSource) then
    FDataSource.DataSet := nil; // On débranche le dataset du TDataSource
  FMessages := pMessages;
  FreeOnTerminate := True; // Le thread s'autodétruit en fin de traitement
end;
  
constructor TDataSetThread.Create(pDataSource: TDataSource; pMessages: TStrings);
begin
  inherited Create(true); // Le thread est créé suspendu
  initialisation(pDataSource.DataSet, pDataSource, pMessages);
end;
  
constructor TDataSetThread.Create(pDataSet: TDataSet; pMessages: TStrings);
begin
  inherited Create(true); // Le thread est créé suspendu
  initialisation(pDataSet, nil, pMessages);
end;

4.3. Les méthodes

Méthode Execute
procedure TDataSetThread.Execute;
begin
  inherited;
  try
    FDataSet.Open;
  except
    on e: Exception do
    begin
      FMessage := e.Message;
      Synchronize(ecrireMessage);
    end;
  end;
  Synchronize(FinTraitement);
end;

Autres méthodes
procedure TDataSetThread.EcrireMessage;
begin
  // Ecriture du message dans la liste des messages
  if assigned(FMessages) then
    FMessages.Add(FMessage);
end;

procedure TDataSetThread.FinTraitement;
begin
  // On rebranche le DataSet sur le DataSource
  if assigned(FDataSource) then
    FDataSource.DataSet := FDataSet;
end;

5. Exemple d'utilisation

5.1. Exemple simple

Initialisation des propriétés dans le create de la fenêtre
procedure TForm1.FormCreate(Sender: TObject);
begin
  // Remplissage de la liste des alias du BDE
  with TSession.Create(nil) do
  try
    SessionName := 'recupAlias';
    GetAliasNames(ComboBox1.Items);
    ComboBox1.ItemIndex := 0;
  finally
    Free;
  end;
  DataSource1.DataSet := Query1;
  DBGrid1.DataSource := DataSource1;
  Session1.SessionName := 'sessionQuery1';
  Database1.SessionName := Session1.SessionName;
  Database1.DatabaseName := 'databaseQuery1';
  Database1.LoginPrompt := false;
  Query1.SessionName := Session1.SessionName;
  Query1.DatabaseName := Database1.DatabaseName;
end;

Exécution de la requête lors du click sur le bouton
procedure TForm1.Button1Click(Sender: TObject);
begin
  Database1.Close;
  Database1.AliasName := ComboBox1.Text;
  Database1.Params.Values['USER NAME'] := Edit1.Text;
  Database1.Params.Values['PASSWORD'] := Edit2.Text;
  Query1.SQL.Assign(Memo1.Lines);
  // Lancement de la requête dans un Thread :
  with TDataSetThread.Create(DataSource1,Memo2.Lines) do
  begin
    Resume; // Démarre le thread
  end;
end;

5.2. Ajout de l'événement OnTerminate

Modification de TForm1
TForm1 = class(TForm)
...
private
  procedure ThreadOnTerminate(Sender: TObject);
...
end;

procedure TForm1.ThreadOnTerminate(Sender: TObject);
begin
  Label1.Caption := 'Requête terminée';
end;

Modification de Button1.Click
procedure TForm1.Button1Click(Sender: TObject);
begin
  Database1.Close;
  Database1.AliasName := ComboBox1.Text;
  Database1.Params.Values['USER NAME'] := Edit1.Text;
  Database1.Params.Values['PASSWORD'] := Edit2.Text;
  Query1.SQL.Assign(Memo1.Lines);
  Label1.Caption := 'Requête en cours...';
  // Lancement de la requête dans un Thread :
  with TDataSetThread.Create(DataSource1,Memo2.Lines) do
  begin
    OnTerminate := ThreadOnTerminate;
    Resume; // Démarre le thread
  end;
end;

6. Autre exemple : l'export vers un fichier texte

6.1. Déclaration de la classe

Déclaration de la classe TDataSetExportThread
TDataSetExportThread = class(TDataSetThread)
private
  FNomFichier : string;
protected
  procedure Execute; override;
public
  constructor Create(pDataSet : TDataSet; pNomFichier : string; pMessages : TStrings = nil); overload;
  constructor Create(pDataSource : TDataSource; pNomFichier : string; pMessages : TStrings = nil); overload;
  property NomFichier : string read FNomFichier write FNomFichier;
end;

6.2. Les constructeurs

Les constructeurs
constructor TDataSetExportThread.Create(pDataSet: TDataSet; pNomFichier: string; pMessages: TStrings);
begin
  inherited Create(pDataSet, pMessages);
  FNomFichier := pNomFichier;
end;

constructor TDataSetExportThread.Create(pDataSource: TDataSource; pNomFichier: string; pMessages: TStrings);
begin
  inherited Create(pDataSource, pMessages);
  FNomFichier := pNomFichier;
end;

6.3. La méthode Execute

La méthode Execute
procedure TDataSetExportThread.Execute;
var
  f : TextFile;
  i : integer;
begin
  try
    if not FDataSet.Active then
      FDataSet.Open
    else
      FDataSet.First;
    Assign(f, NomFichier);
    rewrite(f);
    // Noms des zones
    for i := 0 to FDataSet.FieldCount - 1 do
      if (i = 0) then
        write(f, FDataSet.Fields[i].FieldName)
      else
        write(f, ';' + FDataSet.Fields[i].FieldName);
    writeln(f,'');
    // Le fait de tester Terminated permet d'arrêter l'export
    // en appelant Terminate sur le thread (via un bouton Annuler par exemple)
    while not (FDataSet.Eof) and (not Terminated) do
    begin
      for i := 0 to FDataSet.FieldCount - 1 do
        if (i = 0) then
          write(f, FDataSet.Fields[i].Text)
        else
          write(f, ';' + FDataSet.Fields[i].Text);
      writeln(f,'');
      FDataSet.Next; // (*) voir astuce ci-dessous
    end;
    CloseFile(f);
  except
    on e: Exception do
    begin
      FMessage := e.Message;
      Synchronize(ecrireMessage);
    end;
  end;
  Synchronize(FinTraitement);
end;

(*) Astuce : Le bouton Annuler est utile lorsque l'export est long. Si vous n'avez pas d'export suffisamment long pour tester la classe, il suffit de mettre en commentaire la ligne FDataSet.Next dans la méthode Execute de TDataSetExportThread. La boucle sera alors sans fin, à moins de provoquer le Terminate du thread (dans notre exemple, en cliquant sur Annuler). Attention, si vous ne cliquez pas sur Annuler, le thread va créer un fichier énorme composé uniquement du premier enregistrement, avec les conséquences qui en découlent !

6.4. Intégration dans l'application

Déclaration dans TForm1
TForm1 = class(TForm)
...
private
  currentThread : TThread; // Thread à terminer si click sur Annuler
  procedure ThreadExportOnTerminate(Sender: TObject);
...
end ;

Click sur le bouton Exporter
procedure TForm1.Button2Click(Sender: TObject);
begin
  // Bouton Exporter
  Label1.Caption := 'Export en cours...';
  // on garde un trace du thread afin de pouvoir l'annuler si besoin
  currentThread := TDataSetExportThread.Create(DataSource1,Edit3.Text,Memo2.Lines);
  with TDataSetExportThread(currentThread) do
  begin
    OnTerminate := ThreadExportOnTerminate;
    Resume;
  end;
end;

Click sur le bouton Annuler
procedure TForm1.Button3Click(Sender: TObject);
begin
  // Bouton Annuler
  if assigned(currentThread) then
    currentThread.Terminate;
end;

Evénement OnTerminate de l'export
procedure TForm1.ThreadExportOnTerminate(Sender: TObject);
begin
  Label1.Caption := 'Traitement terminé';
  currentThread := nil;
  // Ouverture du fichier créé
  ShellExecute(0,'open',PChar((sender as TDataSetExportThread).NomFichier),nil,nil,0);
end;

7. Téléchargement